Ολοκληρωτικός Λογισμός

Απλοί υπολογισμοί

Clear["Global`*"]
Integrate[x Exp[a x], x]
Integrate[x Exp[a x], {x, 0, 1}]
Integrate[x Exp[-a^2 x], {x, 0, Infinity}]
NIntegrate[ Exp[-Sqrt[x]], {x, 0, 1}]

\frac{(E^{a x}) (-1+a x)}{a^{2}}

\frac{1+(-1+a) (E^{a})}{a^{2}}

\frac{1}{a^{4}}\,\text{ if }\,Re[a^{2}]>0

0.5284822353142312`

Σειρά Riemann

Clear["Global`*"]

RiemannBar[box : {{x0_, x1_}, {y0_, y1_}}, {x_, y_}, _] := 
 Block[{area = (y1 + y0) (x1 - x0)},  Sow[area];
  {ChartElementData["Rectangle"][box, {}, {}], {Opacity[1], Black, Point[{x, y}]}, 
  If[Abs[area] < 10^-2, {}, {Opacity[1], Black,Rotate[Text[ToString[NumberForm[area, {Infinity, 2}]], Mean /@ box], Pi/2, Mean /@ box]}]}]

RiemannPlot[f_, {x_, x0_, x1_, dx_: 1.}, opts___] := 
 Block[{plot, areas, extent, points, curve},
  extent = OptionValue[Flatten[{opts}], ExtentSize];
  points = 
   If[IntegerQ[dx], RandomReal[{x0, x1}, dx], 
    Switch[extent, Full, Range[x0, x1, dx], Left, 
     Range[x0 + dx, x1, dx], Right, Range[x0, x1 - dx, dx]]]; {plot, 
    areas} = 
   Reap[DiscretePlot[f, Evaluate@{x, points}, opts, ImageSize -> 475, 
     ExtentElementFunction -> RiemannBar, 
     FillingStyle -> Opacity[0.5],  PlotStyle -> PointSize[Small]]];
  Show[plot, Plot[f, {x, x0, x1}], 
   PlotLabel -> 
    ToString@Row[{"Estimated Area: ", Total[Flatten@areas], "; " 
      "Actual Area: ", NIntegrate[f, {x, x0, x1}]}], Frame -> True,   PlotRange -> All, Axes -> {True, False}]  ]

RiemannPlot[BesselJ[5, x], {x, 0, 10, 0.5}, ExtentSize -> Full]
     
RiemannPlot[BesselJ[5, x], {x, 0, 10, 0.25}, ExtentSize -> Full,
     PlotStyle -> ColorData["Crayola"]["Asparagus"]]

Μήκη

Μήκος καμπύλης y=f(x) από το A(a,f(a)) έως το B(b,f(b)).

Clear["Global`*"]
f[x_] := Sqrt[1 - x^2]
a = 0;
b = 1;
Integrate[Sqrt[1 + (f'[x])^2], {x, a, b}]

\frac{\pi }{2}

Μήκος παραμετρικής καμπύλης (x(t),y(t)).

Clear["Global`*"]
x[t_] := Cos[t]
y[t_] := Sin[t]
a = 0;
b = Pi;
Integrate[Sqrt[(x'[t])^2 + (y'[t])^2], {t, a, b}]

\pi

Μήκος πολικής καμπύλης r=f(θ).

Clear["Global`*"]
r[θ_] := 1 - Cos[θ]
a = 0;
b = 2 Pi;
Integrate[Sqrt[(r[θ])^2 + (r'[θ])^2], {θ, a, b}]

8

Εμβαδά

Εμβαδόν του χωρίου που περικλείεται μεταξύ των καμπυλών $r_1=f(θ)$ και $r_2=g(θ)$.

Clear["Global`*"]
r1[th_] := 1
r2[th_] := 1 - Cos[th]
th1 = -Pi/2;
th2 = Pi/2;

1/2 Integrate[Abs[r2[th]^2 - r1[th]^2], {th, th1, th2}]

(\frac{1}{4}) (8-\pi )

Εμβαδόν της επιφάνειας z=f(x,y) πάνω από το $[a,b]\times[c,d]$.

Clear["Global`*"]
f[x_, y_] := x + 2 y
a = 0;
b = 1;
c = 1;
d = 2;

Integrate[Integrate[Sqrt[D[f[x, y], x]^2 + D[f[x, y], y]^2 + 1], {x, a, b}], {y, c, d}]

\sqrt{6}

Εμβαδόν επιφάνειας που παράγεται από την περιστροφή του τόξου AB της y=f(x) ($f(x)\geq0$) περί του x'x.

Clear["Global`*"]
f[x_] := x^2 + x
a = 0;
b = 1;
Integrate[2 Pi f[x] Sqrt[1 + (f'[x])^2], {x, a, b}]

(\frac{1}{32}) \pi (\sqrt{2}+45 (\sqrt{10})+5 ArcSinh[1]-5 ArcSinh[3])

Εμβαδόν επιφάνειας που παράγεται από την περιστροφή του τόξου AB της (x(t),y(t)) περί του των αξόνων.

Clear["Global`*"]
x[t_] := 2 + Cos[t]
y[t_] := 1 + Sin[t]
a = 0;
b = 2 Pi;
(*Περί του x'x. Πρέπει y>=0*)
Integrate[2 Pi y[t] Sqrt[(x'[t])^2 + (y'[t])^2], {t, a, b}]
(*Περί του y'y. Πρέπει x>=0*)
Integrate[2 Pi x[t] Sqrt[(x'[t])^2 + (y'[t])^2], {t, a, b}]

4 ({\pi }^{2})

8 ({\pi }^{2})

Εμβαδόν της παραμετρικοποιημένης επιφάνειας $\vec{r}(u,v)=f (u,v)\vec{e_ 1}+g (u,v)\vec{e_ 2}+h (u,v)\vec{e_3}$.

Clear["Global`*"]
f[u_, v_] := u Cos[v]
g[u_, v_] := u Sin[v]
h[u_, v_] := u
r = {f[u, v], g[u, v], h[u, v]};
a = 0;
b = 1;
c = 0;
d = 2 Pi;

Integrate[ Integrate[Norm[Cross[D[r, u], D[r, v]]], {u, a, b}], {v, c, d}]

(\sqrt{2}) \pi

Όγκοι

Όγκος στερεού με εμβαδόν διατομής A(x) από x=a έως x=b.

Clear["Global`*"]
A[x_] := Pi x^2
a = 1;
b = 2;
Integrate[A[x], {x, a, b}]

\frac{7 \pi }{3}

Όγκος στερεού που παράγεται από την περιστροφή του τόξου AB της y=f(x) ($f(x)\geq0$) περί του x'x.

Clear["Global`*"]
f[x_] := x^2
a = 1;
b = 2;
Integrate[Pi f[x]^2, {x, a, b}]

\frac{31 \pi }{5}